excel函数IFNA ISNA判断是否 VLOOKUP IF TEXTJOIN FILTER SEARCH ISNUMBER函数
excel函数IFNA ISNA判断是否 VLOOKUP IF TEXTJOIN FILTER SEARCH ISNUMBER函数
1.IFNA
作用：在名为“新交易租客欠款”的工作表的 C 列中查找与当前表 A3 单元格相同的值，并返回其对应 D 列的内容。如果找不到，则显示 0，避免出现 #N/A错误。
=IFNA(VLOOKUP(A3, 新交易租客欠款!C:D, 2, FALSE), 0)
IFNA(……, 0)
如果 VLOOKUP找不到匹配值，会返回错误 #N/A，此时 IFNA会捕获这个错误并替换为 0。
应用：匹配欠款金额，匹配了则显示金额，未匹配则显示0，而不是#N/A
2.IF ISNA
作用：检查当前表的 A2 单元格中的会员号是否存在于“测试会员号汇总”工作表的 A 列中。如果存在，返回“是”；如果不存在，返回“否”
=IF(ISNA(VLOOKUP(A2, 测试会员号汇总!A:A, 1, FALSE)), "否", "是")
IF(ISNA(...), "否", "是")
如果 ISNA 返回 TRUE（即查找不到），则公式返回“否”。
如果 ISNA 返回 FALSE（即找到了），则公式返回“是”。
应用：匹配是否是测试账号，匹配了则显示 是，未匹配则显示 否，而不是#N/A
3.TEXTJOIN，FILTER
作用：在“车辆类型去重”工作表中，查找所有 A 列等于当前表 A2 值 的记录，将这些记录对应的 B 列值 用逗号连接成一个字符串。
=TEXTJOIN(",", TRUE, FILTER(车辆类型去重!B:B, 车辆类型去重!A:A = A2))
FILTER(车辆类型去重!B:B, 车辆类型去重!A:A = A2)
筛选条件：在“车辆类型去重”表中，找出 A 列值等于当前表 A2 单元格的所有行。
返回结果：这些行对应的 B 列值（返回一个数组）。
TEXTJOIN(",", TRUE, ...)
第一参数：","：用逗号作为分隔符。
第二参数：TRUE：忽略空值（如果 B 列为空则自动跳过）。
功能：将 FILTER 返回的多个值合并为一个字符串，用逗号隔开。
应用：一个车主对应多个车辆及车辆的类型，比如：个人，专业，经营性，则需要匹配出来，同时以逗号分隔。
4.IF ISNUMBER SEARCH
作用：检查 H2 单元格的文本中是否包含“个人车主”这四个字。
=IF(ISNUMBER(SEARCH("个人车主", H2)), "是", "否")
=IF(ISNUMBER(SEARCH("代管车", H2)), "是", "否")
=IF(ISNUMBER(SEARCH("托管车", H2)), "是", "否")
=IF(ISNUMBER(SEARCH("专业车主", H2)), "是", "否")
=IF(ISNUMBER(SEARCH("经营性车主", H2)), "是", "否")
SEARCH("个人车主", H2)
在 H2 单元格的文本中查找“个人车主”这个关键词。
如果找到，返回“个人车主”在文本中首次出现的位置（是一个数字）。
如果找不到，返回错误值 #VALUE!
ISNUMBER(...)
判断 SEARCH函数的返回值是否是数字。
如果是数字（表示找到了），返回 TRUE。
如果是错误值（表示没找到），返回 FALSE。
IF(ISNUMBER(...), "是", "否")
如果为 TRUE，返回“是”。
如果为 FALSE，返回“否”。